LU_test_No3.zip三角関数、逆三角関数、その他関数、 連立一次方程式の解法 に戻る
連立一次方程式の解法４
連立一次方程式の解法の続きです。
LとUの二つの行列に分けるのでは無く、一つの配列でLUにする場合で連立方程式の解法３と同じですが、連立方程式の解法３との差は、LUの値が、連立方程式の解法１と同じ値になることです。
Uの対角１の値の部分は、L(赤)に割り当てられます。
8,
2, 3, 4
2, 3, 2, 3
6,
5, 4, 5
7, 8, 9, 8
ピボット操作は入っていませんが、容易にピポッド操作を追加可能です。
計算結果は、連立一次方程式の解法１と変わりません。
プログラム
unit Main;
interface
uses
Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.Buttons, Vcl.Grids, system.UITypes,
Vcl.ExtCtrls;
type
TForm1 = class(TForm)
BitBtn1: TBitBtn;
Memo1: TMemo;
StringGrid1: TStringGrid;
StringGrid2: TStringGrid;
LabeledEdit1: TLabeledEdit;
BitBtn2: TBitBtn;
RadioGroup1: TRadioGroup;
LabeledEdit2: TLabeledEdit;
CheckBox1: TCheckBox;
procedure BitBtn1Click(Sender: TObject);
procedure FormCreate(Sender: TObject);
procedure BitBtn2Click(Sender: TObject);
procedure RadioGroup1Click(Sender: TObject);
private
{ Private 宣言 }
function LUecomposition: byte;
procedure GridSet(Sin, Colin: integer); // グリッドサイズ変更
procedure rowmatinc(lc : integer);
procedure testset;
public
{ Public 宣言 }
end;
var
Form1: TForm1;
implementation
{$R *.dfm}
var
Nltest : integer = 4; // テストデーター行列数
// テストデーター
mattestA : array[0..3] of array[0..3] of extended = ((8, 16, 24, 32),
(2, 7, 12, 17),
(6, 17, 32, 59),
(7, 22, 46, 105));
mattestB : array[0..3] of array[0..3] of extended = ((8, 16, 24, 32),
(2, 7, 12, 17),
(2, 17, 32, 0),
(7, 0, 0, 105));
mattestC : array[0..3] of array[0..3] of extended = ((8, 34, 24, 32),
(2, 7, 0, 0),
(24, 17, 0, 0),
(7, 0, 0, 0));
mattestD : array[0..3] of array[0..3] of extended = ((0, 0, 24, 32),
(2, 7, 0, 0),
(0, 0, 32, 59),
(0, 5, 0, 0));
btestA : array[0..3] of extended = (160, 70, 198, 291);
btestB : array[0..3] of extended = (150, 60, 10, 40);
Nl : integer; // 行列数
matA : array of array of extended; // A行列配列
b : array of extended;
a : array of array of extended;
rowNo : array of integer;
lc : integer;
diagonal : integer;
allowable_errorr : extended;
epsilon : extended;
bakA : array of array of extended; // A行列配列
bakB : array of extended;
// グリッドの設定
procedure TForm1.GridSet(Sin, Colin: integer); // グリッドサイズ変更
var // データー行の数は10迄
H, W, i :integer; // それ以上はスクロールする
begin
inc(Sin);
inc(Colin);
StringGrid1.ColCount := Colin;
StringGrid1.RowCount := Sin;
if Sin <= 11 then // ストリンググリッドの大きさ設定
begin // 固定行を含め11行又はそれ以下の場合
H := (StringGrid1.DefaultRowHeight + 1) * Sin;
StringGrid2.ScrollBars := ssNone; // スクロールバー表示
end
else
begin // 固定行を含め11行より多い場合
H := (StringGrid1.DefaultRowHeight + 1) * (10 + 1);
StringGrid2.ScrollBars := ssVertical; // スクロールバー表示
end;
if Colin <= 11 then // ストリンググリッドの大きさ設定
begin // 固定行を含め11行又はそれ以下の場合
W := (StringGrid1.DefaultColWidth + 1) * Colin;
StringGrid1.ScrollBars := ssNone; // スクロールバーなし
end
else
begin // 固定行を含め11行より多い場合
W := (StringGrid1.DefaultColWidth + 1) * (10 + 1);
StringGrid1.ScrollBars := ssBoth; // スクロールバー表示
end;
StringGrid1.ClientWidth := W;
StringGrid1.ClientHeight := H;
for i := 1 to Sin - 1 do StringGrid1.Cells[0,i] := 'a' + intTostr(i) + '*';
for i := 1 to Sin - 1 do StringGrid1.Cells[i,0] := 'a*' + intTostr(i);
StringGrid2.RowCount := Sin;
StringGrid2.ClientHeight := H + 1;
StringGrid2.ClientWidth := (StringGrid2.DefaultColWidth + 1) * 2;
for i := 1 to Sin - 1 do StringGrid2.Cells[0, i] := intTostr(i);
StringGrid2.Cells[1, 0] := 'b*=';
end;
// 行の入れ替え
procedure TForm1.rowmatinc(lc : integer);
var
ss : extended;
i, m, p : integer;
begin
p := lc - 1;
if p < 0 then p := Nl + p;
for i := 0 to Nl - 1 do begin
ss := matA[lc, i];
matA[lc,i] := matA[p, i];
matA[p, i] := ss;
end;
ss := b[lc];
b[lc] := b[p];
b[p] := ss;
m := rowNo[lc];
rowNo[lc] := rowNo[p];
rowNo[p] := m;
end;
// 消去法による連立方程式の解法 Lu分解
function TForm1.LUecomposition: byte;
const
sp = ' ';
var
i, j, k, n, h : integer;
sum, lu : extended;
x, y : array of extended;
LL, spl : string;
begin
setlength(a, Nl, Nl);
setlength(x, Nl);
setlength(y, Nl);
memo1.Clear;
// matデーターを編集用にコピー matA, B
for j := 0 to Nl - 1 do begin
for k := 0 to Nl - 1 do begin
a[j, k] := matA[j, k];
end;
end;
diagonal := Nl;
// Lu分解 前進消去
for i := 0 to Nl-1 do begin
// L_ijの計算
for j := 0 to i do begin
lu := a[i, j];
for k := 0 to j - 1 do lu := lu - a[i, k] * a[k, j];
a[i, j] := lu;
end;
// u_iiの計算
for j := i + 1 to Nl - 1 do begin
lu := a[i, j];
for k := 0 to i - 1 do lu := lu - a[i, k] * a[k, j];
// 対角がゼロだったら行移動フラグセットし終了
if a[i, i] = 0 then begin
result := 1;
diagonal := i;
exit;
end;
a[i, j] := lu / a[i, i];
end;
end;
// 前進代入 bからyを計算
for i := 0 to Nl - 1 do begin
lu := b[i];
for j := 0 to i - 1 do lu := lu - a[i, j] * x[j];
// 対角がゼロだったら行移動フラグセットし終了
if a[i, i] = 0 then begin
result := 1;
diagonal := i;
exit;
end;
x[i] := lu / a[i, i];
end;
// 後退代入 yからxを計算
for i := Nl - 1 downto 0 do begin
lu := x[i];
for j := i + 1 to Nl - 1 do lu := lu - a[i, j] * x[j];
x[i] := lu;
end;
// 各行代入答えの差分計算
for j := 0 to Nl - 1 do begin
sum := 0;
for i := 0 to Nl - 1 do begin
sum := sum + matA[j, i] * x[i];
end;
y[j] := b[j] - sum;
end;
// ループ数 演算行No表示
LL := ' 計算行順 ';
for i := 0 to Nl - 1 do begin
if i < NL - 1 then LL := LL + intTostr(rowNo[i] + 1) + ','
else LL := LL + intTostr(rowNo[i] + 1);
end;
memo1.Lines.Append(LL);
// 行番号表示
memo1.Lines.Append('行 No 検算による差分');
for k := 0 to Nl - 1 do begin
LL := 'No = ' + inttostr(k + 1);
n := 25 - length(LL);
spl := '';
for j := 1 to n do spl := spl + sp;
memo1.Lines.Append(LL + spl + floattostr(y[rowNo[k]]));
end;
// 判定
h := 0;
for k := 0 to Nl - 1 do begin
if abs(b[k]) > allowable_errorr then sum := y[k] / b[k]
else sum := y[k];
if abs(sum) > allowable_errorr then inc(h);
end;
if checkbox1.Checked = false then begin
if h = 0 then memo1.Lines.Append('判定 OK')
else memo1.Lines.Append('判定 NG');
if h > 0 then begin
result := 3;
diagonal := 2;
exit;
end;
end;
// xの値表示
for k := 0 to Nl - 1 do begin
memo1.Lines.Append('X' + inttostr(k + 1) + '=' + floatTostr(x[k]));
end;
result := 0;
end;
procedure TForm1.BitBtn1Click(Sender: TObject);
var
i, j, ch, k : integer;
maxb, minb, bc : extended;
acmax : array of extended;
acmin : array of extended;
procedure sortdat;
var
k : integer;
begin
ch := 1;
for k := 3 to Nl do ch := ch * k; // 最大ループ数計算 理論値の1/2
// Lu分解連立方程式の解法 解法できない場合あり
i := 0;
j := 0; // 解法できた場合 0 出来ない場合 1 対角値0の場合 2
// Lu分解が正常に終了するまで繰り返す
for k := 1 to ch do begin
lc := Nl;
repeat
j := LUecomposition;
if j = 1 then begin // 対角にゼロが発生
dec(lc);
inc(i);
rowmatinc(lc); // 行の移動
end
else lc := 0;
until (lc <= 0) or (j = 2) or (i >= ch);
if (j = 0) or (i >= ch) then break; // 対角値 0 か 解法で終了
end;
end;
begin
setlength(matA, Nl, Nl);
setlength(b, Nl);
setlength(rowNo, Nl);
setlength(acmax, Nl);
setlength(acmin, Nl);
setlength(bakA, Nl, Nl);
setlength(bakb, Nl);
// matAにグリッド1から値読み込み
for i := 0 to Nl - 1 do
for j := 0 to Nl - 1 do begin
val(StringGrid1.Cells[i + 1,j + 1],matA[j,i], ch);
if ch <> 0 then begin
MessageDlg('a' + intTostr(j + 1) + ',' + intTostr(i + 1) + ' の入力値の' + intTostr(ch) + '文字目に誤りが有ります。', mtInformation,[mbOk], 0);
exit;
end;
end;
// bにグリッド2から値読み込み
for i := 0 to Nl - 1 do begin
val(StringGrid2.Cells[1, i + 1], b[i], ch);
if ch <> 0 then begin
MessageDlg('b' + intTostr(i + 1) + 'の入力値の' + intTostr(ch) + '文字目に誤りが有ります。', mtInformation,[mbOk], 0);
exit;
end;
end;
// 検算許容誤差
val(labelededit2.Text, allowable_errorr, ch);
if ch <> 0 then begin
MessageDlg('検算誤差許容値の入力値の' + intTostr(ch) + '文字目に誤りが有ります。', mtInformation,[mbOk], 0);
exit;
end;
// A行列の最大値最小値検索
for i := 0 to Nl -1 do begin
acmax[i] := 1;
acmin[i] := 1;
if matA[i, 0] <> 0 then acmax[i] := abs(matA[i, 0]);
if matA[i, 0] <> 0 then acmin[i] := abs(matA[i, 0]);
for j := 1 to Nl - 1 do begin
if (abs(matA[i, j]) > acmax[i]) and (matA[i, j] <> 0) then acmax[i] := abs(matA[i, j]);
if (abs(matA[i, j]) < acmin[i]) and (matA[i, j] <> 0) then acmin[i] := abs(matA[i, j]);
end;
end;
// B行列とA行列の比最小値と最大値検索
maxb := abs(b[0]) / acmax[0];
minb := abs(b[0]) / acmin[0];
for i := 1 to Nl - 1 do begin
if abs(b[i]) / acmax[i] > maxb then maxb := abs(b[i]) / acmax[i];
if abs(b[i]) / acmin[i] < minb then minb := abs(b[i]) / acmin[i];
end;
// bの値の範囲が演算桁数の範囲を越えているか判定
bc := minb;
if (minb = 0) and (maxb > 0) then
if maxb >= 1 then bc := 1 / maxb
else bc := maxb;
if (minb > 0) and (maxb > 0) then bc := minb / maxb;
if (minb = 0) and (maxb = 0) then bc := 1;
if checkbox1.Checked = false then
if bc < epsilon then begin
MessageDlg('bの入力値の値が演算の範囲を超えています。', mtInformation,[mbOk], 0);
memo1.Clear;
exit;
end;
// 検算結果の判定値設定
allowable_errorr := allowable_errorr * sqrt(bc);
for i := 0 to Nl - 1 do rowNo[i] := i;
for i := 0 to Nl -1 do begin // 入力データーのバックアップ
bakb[i] := b[i];
for j := 0 to Nl - 1 do
bakA[i, j] := matA[i, j];
end;
// 連立方程式の解法 解法できない場合あり
sortdat; // 順方向計算
if i >= ch then begin // 順方向計算でNGだったら逆方向計算
for k := 0 to Nl - 1 do begin
rowNo[k] := Nl - 1 - k;
b[rowNo[k]] := bakb[k];
for j := 0 to Nl - 1 do
matA[rowNo[k], j] := bakA[k, j];
end;
sortdat;
end;
// 解法出来なかったら
if diagonal < Nl then begin
MessageDlg('解法時対角ゼロが発生しました、入力値を見直して下さい。', mtInformation,[mbOk], 0);
exit;
end;
if j <> 0 then begin
memo1.Clear;
memo1.Lines.Append('答えを見つける事が出来ませんでした。');
end;
memo1.Lines.Append('再計算 Row= ' + intTostr(i));
end;
// テストデーターの選択設定
procedure TForm1.testset;
var
i, j : integer;
begin
GridSet(Nltest, Nltest);
Nl := Nltest;
for i := 1 to Nltest do
for j := 1 to Nltest do begin
case radiogroup1.ItemIndex of
0: StringGrid1.Cells[i,j] := floatTostr(mattestA[j-1, i-1]);
1: StringGrid1.Cells[i,j] := floatTostr(mattestB[j-1, i-1]);
2: StringGrid1.Cells[i,j] := floatTostr(mattestC[j-1, i-1]);
3: StringGrid1.Cells[i,j] := floatTostr(mattestD[j-1, i-1]);
end;
end;
for i := 1 to Nltest do begin
case radiogroup1.ItemIndex of
0: StringGrid2.Cells[1,i] := floatTostr(btestA[i-1]);
1,2,3: StringGrid2.Cells[1,i] := floatTostr(btestB[i-1]);
end;
end;
LabeledEdit1.Text := intTostr(Nltest);
memo1.Clear;
end;
// グリッドサイズの変更
procedure TForm1.BitBtn2Click(Sender: TObject);
var
ch : integer;
begin
val(LabeledEdit1.Text, Nl, ch);
if ch <> 0 then begin
MessageDlg('N数の入力値の' + intTostr(ch) + '文字目に誤りが有ります。', mtInformation,[mbOk], 0);
exit;
end;
GridSet(Nl, Nl);
end;
// テストデーターセット
procedure TForm1.RadioGroup1Click(Sender: TObject);
begin
testset;
end;
// 初期値の設定
procedure TForm1.FormCreate(Sender: TObject);
var
a : extended;
begin
testset;
epsilon := 1;
repeat
epsilon := epsilon / 2;
a := 1 - epsilon;
until a = 1;
epsilon := epsilon * 2;
end;
end.
LU_test_No3.zip
三角関数、逆三角関数、その他関数、 連立一次方程式の解法 に戻る